access新手来看：如何重复上一条记录？

答案：
新手来看：如何重复上一条记录？

 

问题：

如何重复上一条记录？ 


有一个窗体,上面有多个文本框和组合框,因为目录这笔资料与下一笔资料大部门都是一样的,能不能利用COPY功能把上一笔的资料复制到下一笔的相对应的文本框和组合框内.最好是做成按钮式,即一个复制按钮和一个粘贴按钮。

 



方法一：

很多软件里面都有这个功能啊？ 


原理非常简单。

只要添加一个COMMAND BUTTON 就可以了。

添加记录的代码相信大家都知道了。

Private Sub Command16_Click()
On Error GoTo Err_Command16_Click 



    DoCmd.GoToRecord , , acNewRec

Exit_Command16_Click:
    Exit Sub

Err_Command16_Click:
    MsgBox Err.Description
    Resume Exit_Command16_Click
    
End Sub


我们更改一下即可，比如说现在有一个文本框，当然了，实际情况你可以再加代码，或者干脆用CONTROLS循环来做。


Private Sub Command16_Click()
On Error GoTo Err_Command16_Click 


    dim strTemp as string
    strTemp=TextBox1.value
    '原理很简单，先将控件值赋值给变量
    '然后在添加记录后再将该变量值赋值给控件
    DoCmd.GoToRecord , , acNewRec

    TextBox1.value=strTemp
Exit_Command16_Click:
    Exit Sub

Err_Command16_Click:
    MsgBox Err.Description
    Resume Exit_Command16_Click
    
End Sub


另外 Ctrl+'(单引号)可以复制上一条记录同一字段内容。

 



方法二：

用controls循环的代码如下：
Private Sub AutoWriteRecord()
'自适应
On Error GoTo Err_AutoWriteRecord
    Dim D                   '创建一个变量
    Set D = CreateObject("Scripting.Dictionary")
    
    Dim i As Long
    For i = 0 To Me.Controls.Count - 1
        If Me.Controls(i).ControlType = acTextBox _
        Or Me.Controls(i).ControlType = acComboBox _
        Or Me.Controls(i).ControlType = acListBox _
        Or Me.Controls(i).ControlType = acCheckBox _
        Or Me.Controls(i).ControlType = acOptionButton Then
            If Me.Controls(i).Name <> "编号" Then
            '自动编号字段不可写，所以除外，可以用on error resume next 忽略
                D.Add Me.Controls(i).Name, Me.Controls(i).Value
            End If
        End If
    Next i
    '原理很简单，先将控件值赋值给变量
    '然后在添加记录后再将该变量值赋值给控件
    DoCmd.GoToRecord , , acNewRec 


    Dim K
    K = D.keys
    
    For i = 0 To D.Count - 1
        Me.Controls(K(i)).Value = D(K(i))
    Next i
    
    Set D = Nothing
    
Exit_AutoWriteRecord:
    Exit Sub

Err_AutoWriteRecord:
    MsgBox Err.Description
    Resume Exit_AutoWriteRecord
    
End Sub




Private Sub AutoWriteRecord_1(strControlName As String)
'人工定义控件名
On Error GoTo Err_AutoWriteRecord
    Dim D                   '创建一个变量
    Set D = CreateObject("Scripting.Dictionary")
    
    Dim strSName() As String
    strSName = Split(strControlName, ";")
  
    Dim i As Long
    For i = 0 To UBound(strSName) - 1
        D.Add strSName(i), Me.Controls(strSName(i)).Value
    Next i
    '原理很简单，先将控件值赋值给变量
    '然后在添加记录后再将该变量值赋值给控件
    DoCmd.GoToRecord , , acNewRec 


    For i = 0 To UBound(strSName) - 1
        Me.Controls(strSName(i)).Value = D(strSName(i))
    Next i
    Set D = Nothing
    
Exit_AutoWriteRecord:
    Exit Sub

Err_AutoWriteRecord:
    MsgBox Err.Description
    Resume Exit_AutoWriteRecord
    
End Sub




测试：
Private Sub Command16_Click()
    'AutoWriteRecord
    AutoWriteRecord_1 "字段1;字段2;字段4;"
End Sub



 








http://www.access911.net 站长收藏

上一个：Access中以文字方式保存文件名的图片如何在报表中预览？
下一个：Access安全吗？——Access安全性之QA详解