判断IP的来源是电信还是网通

判断ip的来源是电信还是网通,常用于站点的后台程序.典型的做法当然是查询数据库教程,数据库里保存着网通(或电信)的ip范围,然后通过范围搜索来决定该ip是否在网通(或电信)的区间内.不过每次都得查询数据库,效率显然很低.

不多废话,直接开始说一种超快的算法吧.既然要极快,莫过于o(1)的复杂度,所以开辟一巨大的缓冲区,用经典的空间换时间,通过查表一步即可判定.那如何定义表的大小,还有key?先从cnc.txt这个文件看起.
(http://www.etherdream.com/funnyscript/iprange/cnc.txt)

这个文件是中国网通的路由表.仔细观察下,不难发现掩码位数最高不超过24(即255.255.255.0).事实上24位的掩码是非常至少,毕竟一个网通的网段里只划分了256个ip,已是相当的少了.既然掩码位数最多只有24,所以ip的最后一位可以忽略不计,而ip的前3位共有256^3(=16m)的组合.所以将ip的前3位作为key,16m的表长度,正好定义出ip对应网段的表.可以形象如下表示:

    123.0.0.0/24 => table[123.0.0] = true

    202.0.0.0/16 => table[202.0.0] = true
                    table[202.0.1] = true
                    ...
                    table[202.0.255] = true

检测的时候取ip前3位,检测表中对应是否为true即可判断出此ip的类型.事实上,本例中ip只有电信和网通两种状态(非网通网段都当作电信),因此只需1bit即可保存每个记录.这时表占用的内存只需16m/8=2m.下面就用asp教程来实现这功能.

首先将路由表转化成一个2m大小的缓存表.考虑到asp的运行速度,这里事先用c程序直接处理,然后保存为一个2m的二进制文件.asp通过adbdo.stream读取数据流,并缓存在appliction集合中.所谓的数据流其实也就是个byte()变量,可以通过midb,ascb这类二进制函数来处理.

初始化函数:

sub init()
       if lenb(application("cnc")) then
              exit sub
       end if

       with server.createobject("adodb.stream")
              .type = 1
              .open
              .loadfromfile server.mappath("cnc.dat")
              application("cnc") = .read
              .close
       end with
end sub

通过appliction集合的缓存,就不必每次都读取文件.2m大小的内存也是可以接受的.接着就是分析ip地址,将其前3位转换成一个数字,因为这里每个记录是按位(bit)保存的,所以还要整除8来对应到byte()的位置.最后通过mod运算对应到具体字节的具体bit上.听着有些复杂,不过实现起来确是相当的简单:

function ipiscnc(ip)
       dim arr, val
       dim c

       arr = split(ip, ".")
       val = clng(arr(0)) * 65536 + clng(arr(1)) * 256 + clng(arr(2))
       c = ascb(midb(application("cnc"), val 8 + 1, 1))

       ipiscnc = _
              (c and 2^(val mod 8)) <> 0
end function

    ipiscnc(ip),返回ip地址是否为网通.

到此关键的两个函数就大功告成了,接着测试:

sub main()
       on error resume next

       init()

       if err then
              response.write "系统错误: " & err.description
              exit sub
       end if

       dim ip
       ip = request.servervariables("remote_addr")

       if ipiscnc(ip) then
              response.write ip & "属于网通ip"
       else
              response.write ip & "属于电信ip"
       end if
end sub
main()

考虑到init函数需要文件的读取,所以添加了错误捕捉.不过通常情况下ipiscnc是不会错误的,因为remote_addr返回的必然是个正确格式的ip.

每当访问asp时,除了第一次需加载文件外,其余时候只需三四行代码既可以判定,真正实现了空间换时间.

补充：asp教程,高级应用