flash as实现渐变发光滤镜代码

创建一个新的 Flash 文档，并将其保存为 gradientglow.fla。
将下面的 ActionScript 添加到时间轴的第 1 帧：

代码如下

复制代码

import flash.filters.GradientGlowFilter;
// 创建一个新的 shapeClip 实例
var shapeClip:MovieClip = this.createEmptyMovieClip("shapeClip", 10);
// 使用绘图 API 创建形状
with (shapeClip) {
    beginFill(0xFF0000, 100);
    moveTo(0, 0);
    lineTo(100, 0);
    lineTo(100, 100);
    lineTo(0, 100);
    lineTo(0, 0);
    endFill();
}

// 定位形状
shapeClip._x = 100;
shapeClip._y = 100;
// 定义渐变发光
var gradientGlow:GradientGlowFilter = new GradientGlowFilter(0, 45, [0x000000, 0xFF0000], [0, 1], [0, 255], 10, 10, 2, 3, "outer");

// 定义鼠标侦听器，侦听两个事件
var mouseListener:Object = new Object();
mouseListener.onMouseDown = function():Void {
    gradientGlow.strength++;
    shapeClip.filters = [gradientGlow];
};
mouseListener.onMouseMove = function():Void {
    gradientGlow.blurX = (_xmouse / Stage.width) * 255;
    gradientGlow.blurY = (_ymouse / Stage.height) * 255;
    shapeClip.filters = [gradientGlow];
};
Mouse.addListener(mouseListener);

前面的代码分为三部分。第一部分代码使用绘图 API 创建一个正方形，并在舞台上定位该形状。第二部分代码定义一个新的渐变发光滤镜实例，该实例将创建从红色到黑色的发光。第三部分代码定义一个鼠标侦听器，它侦听两个鼠标事件处理函数。第一个事件处理函数是 onMouseDown，它可以导致渐变发光的强度增加。第二个事件处理函数是 onMouseMove，每次当鼠标指针在 SWF 文件中移动时，将调用该函数。鼠标指针距离 Flash 文档的左上角越远，应用的发光效果就越强。

选择"控制">"测试影片"来测试该文档。

补充：flash教程,动画技术